IP地址切换、设置IP批处理.bat
@echo offcls
color 0A
set IP=172.30.6.20
set MASK=255.255.255.0
set GATEWAY=172.30.6.1
set DNS1=202.103.224.68
set DNS2=202.103.225.68
set INTERFACE=本地连接
:MENU
cls
echo.
echo.
echo **********************************
echo.
echo IP地址快速切换
echo.
echo **********************************
echo.
echo 1、快速设置请按
echo.
echo 2、手工设置请按
echo.
echo 3、创建默认请按
echo.
echo 4、自动获取请按
echo.
echo 5、察看状态请按
echo.
echo 6、默认设置请按
echo.
echo 7、退出请按任意键
echo.
set /p KEY= [请输入您的选择：]
if %KEY% == 1 goto QUICK
if %KEY% == 2 goto MANUAL
if %KEY% == 3 goto DEFAULT
if %KEY% == 4 goto DHCP
if %KEY% == 5 goto LOOK
if %KEY% == 6 goto LIST
if %KEY% == "" goto END
echo.
goto END
:LOOK
echo.
ipconfig /all
echo.
echo 本程序默认修改的是“本地连接”的设置
echo.
echo 需要修改请按相应的数字键，
echo.
echo 例如：输入2表示改为“本地连接 2”
echo.
echo 英文操作系统请按e2，任意键继续！
echo.
set /p INTEMP= [请输入本地连接的编号]
if %INTEMP% == 1 set INTERFACE=本地连接
if %INTEMP% == 2 set INTERFACE=本地连接 2
if %INTEMP% == 3 set INTERFACE=本地连接 3
if %INTEMP% == 4 set INTERFACE=本地连接 4
if %INTEMP% == 5 set INTERFACE=本地连接 5
if %INTEMP% == e1 set INTERFACE=Local Area Connection
if %INTEMP% == e2 set INTERFACE=Local Area Connection 2
if %INTEMP% == e3 set INTERFACE=Local Area Connection 3
if %INTEMP% == e4 set INTERFACE=Local Area Connection 4
if %INTEMP% == e5 set INTERFACE=Local Area Connection 5
cls
goto MENU
:QUICK
if exist ip.txt goto QDO
echo.
echo 没有发现默认设置文件！
goto END
:QDO
netsh -f .\ip.txt
echo.
echo 按照默认设置已经完成设置！
goto END
:DEFAULT
netsh -c interface ip dump > .\ip.txt
echo.
echo 默认设置已经生成！
goto END
:DHCP
echo.
echo 快速设置IP地址和DNS为“自动获得”
echo.
netsh interface ip set address "本地连接" dhcp
netsh interface ip set dns "本地连接" dhcp
goto END
:MANUAL
echo.
echo 您选择了手工修改设置。
echo.
echo 默认 ＩＰ地址 是%IP%，回车输入默认地址
set /p IP= [请输入新的 ＩＰ地址:]
echo.
echo 默认 子网掩码 是%MASK%，回车输入默认值
set /p MASK= [请输入新的 子网掩码:]
echo.
echo 默认 网关地址 是%GATEWAY%，回车输入默认地址
set /p GATEWAY= [请输入新的 默认网关:]
echo.
echo 默认 首选DNS服务器 是%DNS1%，回车输入默认地址
set /p DNS1= [请输入新的 首选DNS服务器:]
echo.
echo 默认 备用DNS服务器 是%DNS2%，回车输入默认地址
set /p DNS2= [请输入新的 备用DNS服务器:]
echo.
goto LIST
:LIST
echo 即将对“%INTERFACE%”进行设置
echo.
echo 即将生效的ＩＰ地址 是：%IP%
echo 即将生效的子网掩码 是：%MASK%
echo 即将生效的默认网关 是：%GATEWAY%
echo.
echo 即将生效的首选DNS服务器 是：%DNS1%
echo 即将生效的备用DNS服务器 是：%DNS2%
echo.
set /p REEN= [ 马上更改请按 1 ， 重新设置请按 2 ，退出请按 任意键 ]
if %REEN% == 1 goto DO
if %REEN% == 2 goto MANUAL
GOTO END
:DO
echo.
echo 正在更改IP......
echo.
echo IP地址及子网掩码设置完成
netsh interface ip set address name="%INTERFACE%" source=static addr=%IP% mask=%MASK%
echo 网关地址设置完成
netsh interface ip set address name="%INTERFACE%" gateway=%GATEWAY% gwmetric=0
echo 主DNS地址设置完成
netsh interface ip set dns name="%INTERFACE%" source=static addr=%DNS1% register=PRIMARY
echo 第二DNS地址设置完成
netsh interface ip add dns name="%INTERFACE%" addr=%DNS2% index=2
goto end
:end
echo.
pause
佩服佩服！
页:
[1]